Selection.onSetFocus

Доступность

Flash Player 6.

Синтаксис

someListener.onSetFocus = function( [ oldFocus:Object [, newFocus:Object ] ]){
  // statements;
}

Параметры

oldfocus Объект, теряющий фокус. Параметр необязателен.

newfocus Объект, получающий фокус. Параметр необязателен.

Описание

Событие; оповещение происходит при переходе фокуса с одного объекта на другой. Для использования данного события, Вы должны создать объект-листенер. Затем Вы можете определить обработчик для данного события и, используя Selection.addListener(), добавить объект в список листенеров так, как это показано ниже:

var someListener:Object = new Object();
someListener.onSetFocus = function () {
  // statements
}
Selection.addListener(someListener);

Листенеры позволяют фрагментам кода работать совместно, так как одно событие может отслеживаться одновременно несколькими объектами-листенерами.

Пример

В следующем примере показано, как определить момент перехода фокуса от одного текстового поля к другому. Введите следующий код в новый FLA или AS файл:

this.createTextField("one_txt", 1, 0, 0, 100, 22);
this.createTextField("two_txt", 2, 0, 25, 100, 22);
this.createTextField("three_txt", 3, 0, 50, 100, 22);
this.createTextField("four_txt", 4, 0, 75, 100, 22);

for (var i in this) {
  if (this[i] instanceof TextField) {
    this[i].border = true;
    this[i].type = "input";
  }
}

this.createTextField("status_txt", this.getNextHighestDepth(), 200, 10, 300, 100);
status_txt.html = true;
status_txt.multiline = true;

var someListener:Object = new Object();
someListener.onSetFocus = function(oldFocus, newFocus) {
  status_txt.htmlText = "<b>setFocus triggered</b>";
  status_txt.htmlText += "<textformat tabStops='[20,80]'>";
  status_txt.htmlText += "&nbsp;\toldFocus:\t"+oldFocus;
  status_txt.htmlText += "&nbsp;\tnewFocus:\t"+newFocus;
  status_txt.htmlText += "&nbsp;\tgetFocus:\t"+Selection.getFocus();
  status_txt.htmlText += "</textformat>";
};
Selection.addListener(someListener);

См. также

Selection.addListener(), Selection.setFocus()

Смотреть комментарии LiveDocs

Предыдущая | Следующая | Оглавление